Read the source Luke!

Regular DLLs in Smalltalk

2009-07-22T15:52:00.001+02:00

IMHO this is one of the longstanding feature requests for Dolphin Smalltalk (the other being Unicode support :-)) .

Up to now it was not possible to create normal DLLs in Dolphin. The only thing you could do in Dolphin was creating COM DLLs. But where is the difference between a COM DLL and a normal DLL.

Normal DLL

A normal DLL is a PE module which exports functions. This means its export section contains a list of export function names which point to function ordinals - and these ordinals point to (imagebase-relative) function addresses. After loading a DLL you can get it's address by GetProcAddress(). GetProcAddress does nothing else than trying to find the provided name in the export names table and - if successfull - resolves the address by using the ordinal reference and add the base address (to get an absolute address). However ...

... Dolphin is not able to create those export tables. This is (IMHO) due to the fact that the export table is part of the DLL stub that Dolphin provides. And except for a few minor changes this stub remains unchanched during deployment. Even if Dolphin could change the export table you'd still have the problem, that the "functions" would actually be Dolphin Callbacks ... and the address of those callbacks are not guaranteed to remain constant.

So what is Dolphin able to do?

COM DLL

Dolphin is able to create so called "COM Server DLLs". These COM DLLs are DLLs which "export" COM Objects by using a few predefined regular DLL export functions:
DllRegisterServer(), DllUnregisterServer(), DllCanUnloadNow(), DllGetClassObject().
The first two functions are called to (un-)register the control(s) (and type libs) in the registry. The important stuff is the last function. This is the base to get a COM "Class Factory" which is able to create the COM Instances in the DLL. On the image side this is realized by the IIPDolphin interface (implemented by IPDolphin) and the IIPPlughole Interface.

Dolphin COM DLL/Image interaction

If a process loads a Dolphin COM DLL the embedded image is not started automatically. This only happens once the first COM Call hits the DLL (i.e. via DllGetClassObject()). In this case the image is started and (after some setup) the current IPDolphin's #onStartup method is called. This method queries the current DLL's IIPPlugHole interface. This IPPlugHole Interface is then used to inform the DLL about the current IPDolphin instance.

At this stage the DLL has a (COM Interface) Pointer to the IPDolphin instance. This is then used to forward all the COM stuff into the image and thus allow the image to do most of the COM stuff.
The nice thing about this scheme is that except for a few very low level things most of the COM Implementation is in the image - not in the VM.

You said Regular DLLs! I want them!

So how to do "real" DLLs in Smalltalk. As we already saw it not possible to change the export table - but without export table no "real" DLL.

The trick is to alter the export table after the DLL has been loaded. I found an article dealing with un-exporting a function after the DLL has been called. So I thought it must also be possible to do it the other way around.

To make a long story short: It works.
A bit longer: You have to find the module base address (not that easy ... unless you know how :-) ) and from there walk through the different PE headers until you finally hit a IMAGE_EXPORT_DIRECTORY. This is a structure which basically points to arrays of names, ordinals and (relative) function addresses. So all you have to do is to build new new arrays (including your own names and their associated ExternalCallbacks) and change the struct ... and as I said. It works .... kind of.

What do you mean with "works .... kind of"?

There are two things to be aware of:

When does the export table gets modified?

The export Table of the DLL, as long as it is stored on the disk, does not contain the modified Export Table. It's only modified once the image (at a very early stage) has run. However it seems (PLEASE CORRECT ME if I'm wrong!!!!) that the image is not started until the first COM call hits the DLL. And you can't expect third party apps to first do a COM call to your library before resolving exported functions.

So let me state this as clear as possible: If you know a way to execute Smalltalk code in a DLL w/o any COM stuff going on or even better execute Smalltalk code in any event once the lib gets loaded ... PLEASE tell me!!!! I'll do/did the rest.

Dolphin Smalltalk X6.1 beta does not support DLL deployment!

The current beta is missing the DLL Deployment capability (DLL Stubs are missing). So I did all the testing in 6.0.

Summary

Modifing a modules export table is the way to go. This should cover all use cases of DLL symbols being resolved dynamically (via GetProcAddress()). However I'm quite sure this even works if the dynamic linker does it. And the best thing is ... it's ready!!!!

So if someone can provide me with a way to get my Smalltalk code running in a DLL in any case as early as possible we will be able to have regular DLLs in Smalltalk. And the great thing is that it's all in Smalltalk - no VM suport needed ("it's turtles all the way down ...").

Blocks in Cocoa ... finally

2009-05-09T00:14:00.001+02:00

Apple's Objective-C Implementation and the Cocoa class library is once again getting more similar to Smalltalk. After Panther and Tiger introduced a usable MVC-like framework (Cocoa Bindings) Leopard added garbage collection.

And now it seems that Snow Leopard is getting Blocks as well: https://developer.apple.com/mac/articles/snowleopard/usingblockswithgrandcentraldispatch.html

So it Apple decides to wrap Number and Point as full classes (or do an auto-boxing/un-boxing) IMHO the only remaining difference is the runtime system. In Smalltalk the whole class/method structure is inspectable and changeable during runtime. In ObjC you can query/add classes/methods during runtime. Only removing classes/methods is impossible .... but maybe this will change in Snow Leopard as well.

Just got my Smalltalk BYTE issue!!!!

2009-05-04T20:33:00.001+02:00

I got it! I finally got it! I found an auction on EBay where somebody sold the original 1981 BYTE issue introducing Smalltalk to the world!

Maybe I'm crazy - but I like to collect "original" Smalltalk stuff. I got the green, orange and blue book on Ebay ... and now finally the BYTE issue. What a wonderfull day :-)

Extended STS as Dolphin Smalltalk public source code repository

2008-06-11T18:31:00.001+02:00

I just learned that David Gorisek extended STS for shared repository access. You basically keep your own local (shared) STS repository and publish certain Project Editions to the central repository.

This allows you (or a team) to keep your working repository separated from the shared one. If (and only then) a project edition is "stable" you can push it to the shared repository. That's really awesome.

I am working on something similar - although with a different focus: Some of my packages depend on external files (resources, dlls). So I'm concentrating on embedding these files as well - but Davids solution as one huge advantage: It's available and works today. I'm working with STS on daily basis and can't live w/o it. So go ahead and try it and publish your goodies. This will help the Dolphin community in general IMHO.

You can find all the glory details under sts.gorisek.com. This is an WikiDoc server with an additional STS layer. So you can push your stuff to it and also write WikiPages (i.e. with further instructions).

How to add/modify contextmenu of URLPresenter/IWebBrowser2?

2008-05-22T23:04:00.001+02:00

I just found a newgroup entry asking how to "add/modify contextmenu of URLPresenter". So it's time again to give some examples to a goodie I wrote.

URLPresenterWithContextMenu (in package "US Internet Explorer Extensions") allows you to control which context menu is displayed in a WebControl:

If the presenters view #allowContextMenu aspect is false no context menu will be shown. Neither a custom one nor the default one.
If the presenters view #allowContextMenu aspect is true it depends on #contextMenu. If #contextMenu is not nil it will be displayed. If it is nil the default one will be used.

Behind the scenes this presenter implements the IDocHostUIHandlerDispatch interface to get queries for some UI events. The interesting one here is ShowContextMenu() which allows you to allow/prevent the display of the default context menu. I'm using this method for the logic using #allowContextMenu and #contextMenu.

However for using this presenter no digging into COM is needed. Simply use #allowContextMenu and #contextMenu as written above.

Embedding link to file in textbox contents

2008-05-22T22:49:00.002+02:00

I just found a newgroup entry asking how to add "links" to Textboxes. So it's time again to give some examples to a goodie I wrote.

Welcome to "US RichTextEdit Extensions". This goodie enables some capabilites in the Windows RTF control. Surprisingly enough the RTF control already supports Links and is also able to automatically detect URLs and turn them into links. If the link you want is not a URL you have to make them linkable on your own - but thats not very hard.

Let's see some code:


presenter := RichTextPresenter 

            showOn: 'This is my E-Mail Address: mailto:Udo.Schneider@homeaddress.de . 
Just drop me a mail or visit me here: http://readthesourceluke.blogspot.com/' 

                    asRichText.

(presenter view)

    autoUrlDetect: true;

    link: true;

    enableMailtoLinks.

presenter 

    when: #linkClicked:

    send: #value:

    to: 

        [:link | 

        MessageBox notify: link

            caption: 'Link clicked']

So if you have a RichTextPresenter view you can use #autoUrlDetect: to enable/disable the automatic linking of URLs. #link: is used to enable linking in general. So even if #autoUrlDetect is true you won't see any links until you set #link: to true.

The package also contains a method to make mailto: links linkable.
#enableMailtoLinks parses the text and for mailto: links and hides the mailto: prefix so that only the email address remains. However the link itself still contains the mailto: + email combinations. This is a good example how to use non-visible pre- and postfixes for link.

This is i.e. useful if you want to present a "simple link" to the user but need a more descriptive link for your program.

To capture clicked links you simply have to hook up the the #linkClicked: event in your #createSchemanticWiring method. The event parameter is the complete link - not only the user visible part. So in the mailto: link above you will get a "mailto:Udo.Schneider@homeaddress.de" although only "Udo.Schneider@homeaddress.de" is visible to the user.

NotifyArea Icons done right (hopefully this time!)

2008-04-23T00:35:00.001+02:00

I had enough of it. Using the "Traybar" with my NotifyView was a pain in the a.. . I admit it - I'm guilty. So I decided to do it right this time.

My "US NotifyView" package contains a new and natural way to deal with NotifyArea Icons. No need to hassle with views. Simply create one (or many) instance(s) of NotifyAreaIcon and use simply messages like #show, #hide, #icon: and #message. That's it. If you want events simply catch #leftButtonPressed, #leftButtonDoubleClicked, #rightButtonPressed or #rightButtonDoubleClicked.

Using NotifyAreaIcons also gives you two things which are IMHO not part of any other Dolphin Traybar goodie.

Survives Image Reload: If you save/close your image with visible Traybar icons they are restored if you reopen the image
Explorer crash support: If your explorer crashes and rebuilds it's traybar your icons are re-added as well.

The following code illustrates it a bit more. Simply download the newest version of my goodies (04/23/2008) and enjoy.


| notifyIcon notifyIcons |
"Create your instance. No need to hassle with Views. Simply create an instance"
notifyIcon := NotifyAreaIcon 
            icon: (Icon fromId: '!APPLICATION')
            message: 'My Application'.
"If you want your icon to be displayed, simply send #show"
notifyIcon show.
"You can change the tip message and the icon any time by using #icon: and #message: .
If the icon is currently visible it's automatically updated."
notifyIcon 
    icon: Icon defaultApplication.
notifyIcon message: 'Changed message'.
"You can use this i.e. to display animations"
Icon allInstances asSet 
    do: 
        [:each | 
        notifyIcon
            icon: each;
            message: each identifier displayString].
"The icon triggers several messages which you can intercept using the regular
#when:send:to: mechanism"
notifyIcon 
    when: #leftButtonPressed
    send: #value
    to: [Sound beep].
notifyIcon 
    when: #leftButtonDoubleClicked
    send: #value
    to: 
        [Sound beep.
        (Delay forMilliseconds: 500) 
            wait.
        Sound beep].
notifyIcon 
    when: #rightButtonPressed
    send: #value
    to: [Sound bell].
notifyIcon 
    when: #rightButtonDoubleClicked
    send: #value
    to: 
        [Sound bell.
        (Delay forMilliseconds: 500) 
            wait.
        Sound bell].
"If you don't need the icon anymore (e.g. during #onViewClosed) you can simply hide
it or nil the variable and let GC take care of it"
notifyIcon hide.
notifyIcon := nil.

""
"You can even generate a whole bunch of instances"
notifyIcons := Icon allInstances 
            asSet collect: 
                    [:each | 
                    NotifyAreaIcon icon: each
                        message: each identifier displayString].
"If you want to stress test your system, show /all/ icons"
notifyIcons 
    do: [:each | each show].
"Please note, that we don't hide icons here. We simply nil the instance and let GC
take care of it"
notifyIcons := nil.
"You can also force a GC"
MemoryManager current collectGarbage

Did you know? Drag&Drop from Inspector to workspace

2008-04-22T17:43:00.001+02:00

I thought I had a great idea how to improve the IDE. Dragging objects from an inspector to a workspace. This would allow you to work with these objects in a "big" workspace and not within the tiny inspector area. After spending some time browsing the class lib to get a clue how to to it I set a break point and simply dragged and object to a workspace. To my great surprise it worked! Dolphin was doing exactly what I was trying to implement.

So it turned out that OA already implemented what I wanted!!! Once more it seems that DST is the best IDE one can think of. Even the things one dreams of are already there :-)

Flash plugin not installed or too old!

Dolphin Smalltak in PSPad

2008-04-14T18:06:00.009+02:00

IMHO having a good editor and learn to use it is one of the most important things to do when working with computers. And it will save you a lot of time in the long run!!

A few years back I was using UltraEdit until I discovered PSPad. PSPad offers everything I needed and it is free. It also has the concept of scripts written in JScript, VBScript and Python. As the object model also supports COM it's also possible to access external COMponents.

Some time ago I read a blog entry Phasing out TextPad in favor of NOTEPAD++ when I got the idea to embed the workspace text functions of Dolphin Smalltalk into PSPad. Here is what I came up with:

Demo/Installation

Load the "US Dolphin COM Evaluator.pac" package. The install scripts register the coclass and interface automatically.
Register the type library "dolphineval.tlb". You can do this directly from within Dolphin.
Copy "DolphinSmalltalk.js" into PSPad's Script\JScript directory
Enjoy Dolphin Smalltalk in PSPad!!!

Flash plugin not installed or too old!

Useful components from Terra Informatica

2008-04-14T17:40:00.001+02:00

I just found to components on Terra Informatica which might be worth wrapping them in Smalltalk.

HTMLayout

The first one is a HTMLView called "HTMLayout". As far as I understand up to know it simply registers it's own window class and communicates via custom window messages and WM_NOTIFY with the host applications. Both things are pretty straight forward in DST

TIScript
The second one is a ECMA-/JavaScript compatible Scripting component called "TIScript". Browsing through the C header files it seems that embedding and providing (wrapped) Smalltalk objects to it is pretty easy.
Up to now I used BeeBasic as a Scripting Engine. However the vendor seems to have disappeared - so I'm searching for alternatives. And no, WSH is not an alternative!

Ghoul for DST6

2008-04-13T00:22:00.001+02:00

Sometime ago I patched Ghoul to be compatible with DST6 and wrote Chris about it. As it seems that Metagnostic is down and that there will be no further enhancements of Chris' goodies I decided to release it directly.

So here we have Ghoul again running under Dolphin DST6:

You can download the package here. Please note, that you still need a copy of Chris' goodies to have access to the documentation and more.

External Tools in Dolphin Idea Spaces

2008-04-12T23:11:00.003+02:00

Based on a request in c.l.s.d "drag Squeak Shell To Dolphin's IdeaSpace" I decided to investigate an idea I got from an article at codeproject (Hosting .exe applications into a dialog). My goal was to get something similar in Dolphin - but packaged in a nice MVP friendly way.

Here is what I came up with:

ExternalProcessPresenter/ExternalProcessView

This combination allows you to display a external application within a Dolphin View/Presenter. It uses ExternalProcess (from Bob Jarvis Goodies) as it's model. This also means that you cannot wrap already running processes with it. The process has to be started from within Dolphin.

So you'll need the model first:


| externalProcess |
externalProcess := (ExternalProcess new)
    commandLine: (SpecialFolderRelativeFileLocator windows 
        localFileSpecFor: 'system32\sol.exe');
    yourself.

Now we show the presenter:


ExternalProcessPresenter showOn: externalProcess

DONE! This is what you should get:

Cool, isn't it?

ExternalToolShell

It even get's better. I added a Dolphin Smalltalk Integration to manage a set of external tools and run them within IdeaSpaces. Start the external Tools shell from the addition Tools folder and you'll get a shell with a List of known tools on the left. You are able to add and delete external tools and start them via double click. This allows you to e.g. run Squeak within Dolphin:

I hope this is useful for somebody.

WARNINGS/LIMITATIONS

This goodie is a Hack!!! - even for a Windows app. So you have been warned!!!
Single toplevel Window Applications only: If the application opens multiple top level windows only one will be shown in an IdeaSpace!
Force quit on View close: Currently the process' view is destroyed and the process terminated if the ExternalProcessView is closed. There is no onClose Handling
Redraw problems: Some controls (especially menus) have redraw problems. This is due to the fact that Windows never intended an application to have a MenuBar in a non-TopLevel Window
Focus Problem: When interacting with controls within the window the parent shell (IdeaSpace) looses the focus.

Download
Just download the newest version of my goodies and have fun!

Autocomplete with Images

2008-03-28T17:29:00.001+01:00

My Autocomplete extensions are now part of the goodies package. What's new compared to the last version:

Survives Image Reload

This version deals with image exits/loads and (re-)creates the image cache if needed.

New functionalities

Different MessageSend icons depending on whether you are sending a "normal", private, public, deprecated or development system message.

New Images

: self

: super

: thisContext

: Class Variable

: Instance Variable

: Method Variable (Argument or temp)

: "Normal" method

: Public method

: Private method

: Deprecated method

: Development method

With this goodie it's more important than ever to use good looking class icons (see also Keep it candy) as they are not only shown in the Class Browser but in every Autocompletition menu as well :-)

Filenames from Clipboard and via native Drag&Drop

2008-03-28T15:21:00.002+01:00

I just found two tiny packages which might help you to improve the native integration of your app with Windows. Both deal with getting file(names) from the user.

1) Clipboard (US Clipboard Extensions)
You can get filenames from the Clipboard using #getFilenamesIfNone: or simply using #getFilenames:


filenames := Clipboard current  getFilenamesIfNone: [].
filenames := Clipboard current getFilenames.

2) (Native) Drag&Drop (US DragAndDrop Extensions)
This package allows you to get filenames from a Drag&Drop Session using #dragFilenames::


filenames := aDragDropSession  dragFilenames

E.g. you can use it in the following D&D code:


onDragOverList: aDragDropSession 
    | filenames |
    filenames := self 
                filterFilenames: aDragDropSession dragFilenames.
    aDragDropSession 
        operation: (filenames notEmpty 
                ifTrue: [#copy]
                ifFalse: [#none])

onDropOverList: aDragDropSession 
    | filenames |
    filenames := self 
                filterFilenames: aDragDropSession dragFilenames.
    filenames notEmpty 
        ifTrue: 
            [self addFiles: filenames]

#filterFilenames: is one of my methods which selects only extensions acceptable for the Application.

Both packages are part of my goodies which are available on this site.

Dolphin Map - To Do List

2007-11-21T10:04:00.001+01:00

Clean up backend code
Polish up the natvie GUI
Built a Seaside frontend

Dolphin Map Online Repository works

2007-11-21T10:03:00.001+01:00

The client and server side is ready. Due to Swazoo it was very easy to create a DolphinMap resource to accepts client requests. As the client uses standard HTTP for communication this should also work w/o problems behind firewalls and in proxy setups.

Dolphin Map is comming along...

2007-11-19T12:04:00.001+01:00

DolphinMap just hit its first Milestone. The current version is able to:

Use a local file based repository
Import Packages (and/or additional files) into Bundles
Sign Bundles with Dolphin Sure certificates
Export Bundles to filesystem
Export Bundles as Zip
Manage Bundles (Update and Delete)

The next step is an online repository which will allow us to move/copy bundles between different repositories.

Although not yet complete I'm already using it on a daily basis for Zip File creation. You simply define once what's in a bundle (packages and additional files like icons and documentation) and then simply update bundles if anything changes. These bundles can then easily be exported to zip files.

My Image Startup script

2007-11-16T17:30:00.001+01:00

Following a previous post some people asked me how my Image Startup script looks like. Well - here it is. I run this script in a clean image and it sets all the correct bits and pieces and loads all necessary packages.


Transcript clear.

"Set personal Settings"
(SmalltalkSystem current)
    autoFormatMethodSource: true;
    showSplashAtStartup: false.
SmalltalkSystem current tipOfTheDayClass 
    showTipsAtStartup: false.
SmalltalkSystem current 
    workspaceShellClass variableTips: true.
"Connect STS Repositry"
stsRepositryPath := 'S:\Dolphin Smalltalk X6\STS Repositry'.
StsManager startUpOn: stsRepositryPath.
"Backup Repositry and reorganize"
stsBackupPathStream := ReadWriteStream 
            on: String new.
stsBackupPathStream
    nextPutAll: stsRepositryPath;
    nextPutAll: '/Repository.BACKUP_'.
Date today 
    printOn: stsBackupPathStream
    format: 'yyyyMMdd'.
Time now 
    printOn: stsBackupPathStream
    format: 'HHmmss'.
(StsManager current databaseConnection)
    createBackupOn: stsBackupPathStream contents;
    reorganize.
"Install Restore as this can't be loaded from STS"
Package manager install: 'S:\Dolphin Smalltalk X6\Solutions Software\ReStore120_D6\SSW ReStore MVP.pac'.
"Packages to ignore"
ignorePackageNames := #('US ActiveX' 'US Speedometer Control').
"Find all US Packages to be loaded"
loadPackageNames := ((StsManager 
            current getAllPackageNames 
            select: 
                [:eachPackageName | 
                eachPackageName beginsWith: 'US']) 
                reject: 
                    [:eachPackageName | 
                    ignorePackageNames 
                        includes: eachPackageName]) 
                asOrderedCollection.
"Load Packages and Prerequsisites"
[loadPackageNames notEmpty] whileTrue: 
        [currentPackageName := loadPackageNames 
                    removeFirst.
        stsPackage := (StsManager current 
                    getPackageEditionsFor: currentPackageName) 
                        first.
        prerequisitePackageNames := (stsPackage 
                    prerequisiteNames reject: 
                            [:each | 
                            (ignorePackageNames includes: each) 
                                or: 
                                    [Package manager 
                                        includesPackageNamed: each]]) 
                    asOrderedCollection.
        prerequisitePackageNames isEmpty 
            ifTrue: 
                [stsPackage isLoaded 
                    ifFalse: [stsPackage load]]
            ifFalse: 
                [loadPackageNames := loadPackageNames 
                            , prerequisitePackageNames.
                loadPackageNames 
                    addLast: currentPackageName]]

New version of Seaside (IDB Package clash fixes)

2007-11-13T18:07:00.001+01:00

Esteban just published an updated version of Seaside which fixes the package clash problems I had.
That's IMHO one of the great things in the Dolphin Community: Reaction times are absolutely amazing. I'm loving it.

Can't connect to Seaside (SOLVED)

2007-11-13T15:24:00.002+01:00

It seems that accessing Dolphin/Seaside is only possible using the URL http://localhost:8888/seaside. Every other host (e.g. "127.0.0.1" or an external IP) doesn't work. This definitely limits it's use - however I cannot imagine that this is a bug. I think this is intended behavior which I simply do not understand.

UPDATE:
This was indeed intended behavoir - of Swazoo in this case. Swazoo uses "Sites" defined by hostname, ip and port to offer virtual hosting. And these Site definitions are very strict. E.g.


site := Site new 

            name: 'seaside'.

site 

    host: 'localhost'

    ip: '127.0.0.1'

    port: 8888.

site 

    addResource: (composite := CompositeResource 

                    uriPattern: '/').

composite 

    addResource: (SeasideSwazooResource 

            uriPattern: 'seaside').

site

    addAlias: (SiteIdentifier 

                ip: '127.0.0.1'

                port: 8888

                host: 'localhost');

    addAlias: (SiteIdentifier 

                ip: '127.0.0.1'

                port: 8888

                host: '172.16.1.128').

SwazooServer singleton 

    addSite: site.

SwazooServer start

This site definition will listen only to http://localhost:8888/seaside/. Even http://127.0.0.1:8888/seaside/ won't work as 127.0.0.1 does not equal localhost for Swazoo (although it does for DNS).

The solution is to use Site Aliases to allow Swazoo to handle thos situations. E.g.:


site

    addAlias: (SiteIdentifier 

                ip: '127.0.0.1'

                port: 8888

                host: '127.0.0.1');

    addAlias: (SiteIdentifier 

                ip: '127.0.0.1'

                port: 8888

                host: '172.16.1.128')

This allows the site to be called using http://127.0.0.1:8888/seaside/ and http://172.16.1.128:8888/seaside/.

Finding my way through Seaside/Dolphin

2007-11-13T15:08:00.001+01:00

I started to play around with Seaside 2.8 on Dolphin. It seems that there are some dependencies (with my code?) which I am not quit able to trace. When loading the project editions from STS into a clean image everything works ...
However as I'm rebuilding my image daily with a script based on STS package editions I cannot (yet) load project editions manually. I either have to find out how to tackle this dependency problem or extend my script to load the project editions before doing anything else.

... Stay tuned

Getting the STS/Seaside wrapper up to speed

2007-11-13T10:59:00.001+01:00

Just started to clean up the dust from a Seaside/STS wrapper I wrote. I stopped working on it when I discovered that uploading files didn't work with the 2.6 Dolphin port. With a working 2.8 port right now it's time to start again.